よねさん、こんにちは。
いつも拝見しております。
ご教授頂きたいことがあり書き込ませて頂きます。

excelで毎日の注文を整理し、日々の注文書とそれとは別にデータを蓄積するシートを作りたいのですが行き詰ってしまっています。
どうかご教授お願い致します。

　　 　A　　 　B　 　　　C　　 　　D　　　　E
1　=today()

2   　　　　　九州 　　関西　　　関東　　 東北

3　　白菜　　　100　　　200　　　300　　　400　　　　　　　　

4    人参　　　200　　　300　　　400　　　500

5　　大根　　　300　　　400　　　500　　　600


↑このような表が入ったシート1があり、毎日その日の各地域からの注文書をみて
B3:E5までを入力しています。

シート2に、

　　 　A　　 　B　 　　　C　　 　　D　　　　E
1   10/4　　　九州 　　白菜　　　300
2　 10/4　　　九州　　 人参　　　350　　　
3   10/4　　　九州　   大根　　　400
4　 10/4　　　関西　   白菜　　　100
5　 10/4      関西　   人参　　　500
6　 10/4      関西　   大根　　　200
7   10/4      関東　　 白菜　　　300
8   10/4      関東　   人参      150
9   10/4      関東     大根      200
10  10/4      東北　　 白菜　　　500
11　10/4　　　東北　　 人参      300
12　10/5　　　九州　　 白菜　　　500
13　10/5　　　九州　   人参　　　100
・
・
と日付+納品先の地域名+商品名+数量を蓄積していきたいのです。

調べたところ、マクロを使用して…とのことなのですがマクロは理解できていないのでexcelで簡単にできないものかと考えております。

なので、逆に毎日の数量入力をシート2にし、シート1を関数で完成できれば良いのかなと思うのですが、
単なるvlookupでは突破できず、
日付、地域、商品名、この３つの条件でシート1のB3:E5にデータをかえすための
知恵をお借りできないでしょうか。

宜しくお願い致します。

VLOOKUP関数を使う場合、検索値がデータリストの左側の列に必要です。
その場合は、A列に作業列を設けることになりますが、
お書きのデータなら右側のF列に作業列(検索列)を設けることになりそうなので
INDEX関数で求めることが可能です。
だだし、重複データがないという条件の下でも計算になります。
Sheet2のF1セルに =A1&"_"&B1&"_"&C1　といった作業列を設けます。
Sheet1のB3セルには
=INDEX(Sheet2!$D$1:$D$1000,MATCH($A$1&"_"&B$2&"_"&$A3,Sheet2!$F$1:$F$1000,0))
と入力します。

簡単なのは、SUMIFS関数を使うことだと思います。(Excel2007以降で使用可能です)
この場合は、作業列は不要で、重複データがあると加算されます。
Sheet1のB3セルに
=SUMIFS(Sheet2!$D$1:$D$1000,Sheet2!$A$1:$A$1000,$A$1,Sheet2!$B$1:$B$1000,B$2,Sheet2!$C$1:$C$1000,$A3)
と入力します。

↓下記のページが参考になるかもしれません。
エクセル関数の技：合計する関数の技(1/2)
http://www.eurus.dti.ne.jp/~yoneyama/Excel/waza/goukei.html

12行ごとに+1するのなら、2つ目の行以降に
=IF(MOD(ROW(),12)=0,INDIRECT("A"&ROW()-1)+1,INDIRECT("A"&ROW()-1))

3行ごとに決まった文字列なら、最初の行から
=CHOOSE(MOD(ROW(),3)+1,"AA","BB","CC")
と、いった感じでしょうか?

入力方法で対処するなら、
入力時にショートカットキーを使って同じ値を入力する方法が使えます。
12行ほど同じ日付が入るのなら、1個目を入力して、12個セルを選択して、
[Ctrl]+[D]で一番上の値を入力するのはいかがでしょうか?
A12に2018/10/25　と入力したら、 A12:A24を選択して、[Ctrl]+[D]とします。

また、"AA","BB","CC"　と入力したセルをフィルドラッグすると(オートフィルで)
同じ値が繰り返し入力できます。

このようなことを考えましたが、いかがでしょうか?