↓が参考になると思います。
コンボボックスにデータを追加する
http://officetanaka.net/excel/vba/tips/tips157.htm

弊サイト↓で初期設定で　.RowSource を使っているので、ちょっと変更が必要と思います。
http://www.eurus.dti.ne.jp/~yoneyama/Excel/vba/vba_userform05.html


コンボボックスの初期値は シートのA2:A3といったセル範囲にあらかじめ入力しておきます。
コンボボックスで新しい値を入力したら、コマンドボタンでコンボボックスと、シートのA2以降のセルに追加します。
こんな感じでいかがでしょうか?

Private Sub CommandButton1_Click()
    Dim i As Long, Flag As Boolean
    Dim lRow As Long
    With ComboBox1
        If .Text = "" Then Exit Sub
        For i = 1 To .ListCount
            If .Text = .List(i - 1) Then
                Flag = True
                Exit For
            End If
        Next i
        If Not Flag Then
            .AddItem .Text
            lRow = Worksheets("Sheet1").Range("A" & Rows.Count).End(xlUp).Row
            Worksheets("Sheet1").Range("A" & lRow + 1).Value = .Text
        End If
    End With
    
End Sub
Private Sub UserForm_Initialize()
    Dim lRow As Long
    Dim i As Long
        With Worksheets("Sheet1")
            lRow = .Range("A" & Rows.Count).End(xlUp).Row
        End With
        With ComboBox1
        For i = 2 To lRow
            .AddItem Worksheets("Sheet1").Range("A" & i).Value
        Next i
        End With
End Sub