よねさんのWordとExcelの小部屋　なんでも掲示板 [One Tree All Message]

よねさんのWordとExcelの小部屋　なんでも掲示板

ツリー一括表示
IF複数条件 /taka (19/10/28(Mon) 10:34) #13424
`└` Re[1]: IF複数条件 /よねさん (19/10/29(Tue) 14:41) #13425
`└` Re[2]: IF複数条件 /よねさん (19/10/30(Wed) 08:00) #13426
`└` Re[3]: IF複数条件 /taka (19/10/30(Wed) 10:52) #13427

親記事　/ ▼[ 13425 ]

■13424 / 親階層)

　IF複数条件

□投稿者/ taka -(2019/10/28(Mon) 10:34:50)

IFを使用して条件を組み込んでありますがもう一つ条件を足したいのですが
どのように組み込んで良いか教えてください。

現状は、
=IF(A69="","",IF(ISNA(VLOOKUP(A69,客先税区分!$A$2:$B$135,2,FALSE)),ROUNDDOWN(D69*0.08,0),IF(VLOOKUP(A69,客先税区分!$A$2:$B$135,2,FALSE)=1,ROUNDDOWN(D69*0.08,0),ROUND(D69*0.08,0))))
上記のような通りです。
ここに同じ行のG69の日付が2019/10/1以前はD69*0.08以降はD69*0.1と加えたいのですが・・・

[ □ Tree ] 返信/引用返信 削除キー/

▲[ 13424 ] / ▼[ 13426 ]

■13425 / 1階層)

　Re[1]: IF複数条件

□投稿者/ よねさん -(2019/10/29(Tue) 14:41:36)

A69とG69の値の関連性がどういう風なのかわかりませんが、
G69の日付で　0.08と0.1　とを切り替えたいのなら、
計算式の部分でIF関数で切り替えたらよいと思います。
↓のような感じです。
=IF(A69="","",IF(ISNA(VLOOKUP(A69,客先税区分!$A$2:$B$135,2,FALSE)),
ROUNDDOWN(D69*IF(G69>=DATE(2019,10,1),0.1,0.08),0),
IF(VLOOKUP(A69,客先税区分!$A$2:$B$135,2,FALSE)=1,
ROUNDDOWN(D69*IF(G69>=DATE(2019,10,1),0.1,0.08),0),
ROUND(D69*IF(G69>=DATE(2019,10,1),0.1,0.08),0))))

[ 親 13424 / □ Tree ] 返信/引用返信 削除キー/

▲[ 13425 ] / ▼[ 13427 ]

■13426 / 2階層)

　Re[2]: IF複数条件

□投稿者/ よねさん -(2019/10/30(Wed) 08:00:18)

Excel2013以降をお使いなら、IFNA関数が使えますので
ちょっと計算過程が見た目がわかりやすくなると思います。

=IF(A69="","",IFNA(IF(VLOOKUP(A69,客先税区分!$A$2:$B$135,2,FALSE)=1,
ROUNDDOWN(D69*IF(G69>=DATE(2019,10,1),0.1,0.08),0),
ROUND(D69*IF(G69>=DATE(2019,10,1),0.1,0.08),0)),
ROUNDDOWN(D69*IF(G69>=DATE(2019,10,1),0.1,0.08),0)))

[ 親 13424 / □ Tree ] 返信/引用返信 削除キー/

▲[ 13426 ] / 返信無し

■13427 / 3階層)

　Re[3]: IF複数条件

□投稿者/ taka -(2019/10/30(Wed) 10:52:15)

お世話になっております。

解決いたしました。
いつも有難うございます。
知らない関数がまだまだ、いっぱいあることに気づかされます。
とても勉強になります。

[ 親 13424 / □ Tree ] 返信/引用返信 削除キー/

HOME HELP 新規作成新着記事ツリー表示トピック表示検索過去ログ

- Child Tree -