こんばんは、いつもお世話になっております。

Excel2003で以前質問した時の表を変えて

　　　Ａ　　　　　　Ｂ　　　　　　　　　Ｃ　　　　　Ｄ　
　（コード）　　（部門）　　　　　　（エリア）　　（所属店舗）　　　　
１  　1100　　　　本店レストラン　　東京都中央区　　　本店
２　　1110　　　　本店カフェ　　　　東京都中央区　　　本店
３　　1200　　　　本店物販      　　東京都中央区　　　本店
４　　2100　　　　Ｂ店レストラン　　東京都中央区　　　Ｂ店
５　　2200　　　　Ｂ店物販　　　　　東京都中央区　　　Ｂ店
　　　　
（以下略）

とし、そこから別シートに、VLOOKUPを使ってC2・F2にコード入力で
　　C　　　（略）　　　　F
　やりとり元　　　　　やりとり先
2　1100　　　　　→　　1200
3　本店レストラン　→　本店物販
4　本店　　　　　→　　本店
5　東京都中央区　→　　東京都中央区

と食材や物のやりとり記録をした表を作り、さらに
本店レストラン→本店カフェ・Ｃ店レストラン→Ｃ店カフェのように同店レストラン→カフェは１
本店レストラン→本店物販・Ｂ店レストラン→Ｂ店物販のように同店レストラン→物販は２
本店⇔Ｂ店の同エリア同士は３と

=IF(ISBLANK($C$2),"",IF($C$4=$F$4,"1",IF($C$5=$F$5,"2","3")))
とまた別のセル（仮にT2セル）に出るようにしましたが、ここに更に条件を足して
やりとり元に物販部門が来た場合T2セルに「A」と出るようにしたいです。
MID関数を利用して
IF(MID(F2,2,1)="2"),"A")))
とか入れようとしていますが、「この関数に対して多すぎる引数が入力されています」とメッセージが出てうまくいきません。

長くなってしまいましたが、よろしくお願いいたします。	

> 「この関数に対して多すぎる引数が入力されています」とメッセージが出てうまくいきません。
数式　=IF(MID(F2,2,1)="2"),"A")))　でこのエラーを回避するには
=IF(MID(F2,2,1)="2","A")　とすれば良さそうです。

お書きの数式は下のように[Alt]+[Enter]で改行することができます。
数式バーの高さを変えて表示すると、IF関数のネストがどうなっているかが少しわかりやすくなります。
数式内にカーソルを表示すると、「関数のヒント」が表示されますので、引数がどの部分かがわかるようになって便利です。

=IF(ISBLANK($C$2),"",
IF($C$4=$F$4,"1",
IF($C$5=$F$5,"2","3")　　    ←ここでIF関数は完結しています。IF(論理式,真の場合,偽の場合)
),IF(MID(F2,2,1)="2","A")))　←意味のない付け足しになっています。



1,2,3　とする条件より、A　とする条件を前に持ってくるのではいかがでしょうか?
すべて、IF関数の引数「偽の場合」のところにIF関数が入っています。

=IF(ISBLANK($C$2),"",
IF(MID(F2,2,1)="2","A",
IF($C$4=$F$4,"1",
IF($C$5=$F$5,"2","3"))))

(追加)
Excel2019,Microsoft365をお使いでIFS関数が使える場合は以下の数式でもよろしいと思います。
=IFS(ISBLANK($C$2),"",MID(F2,2,1)="2","A",$C$4=$F$4,"1",$C$5=$F$5,"2",TRUE,"3")

以上です。