教えて下さい。

　　 A   B   C   D   E   F   G　　　　　Y
1 　 7  80   2 　8　　　　　　　　　　　7
2 　 5　　　　　　　　　　　　　　　　 80 
3　  6　21   3                          2　　　　　　
4 　11　79                              8 
5　 47   7                              5　
6    2                                  6
                                       21
                                        3
                                       11

上記表のA1〜G6にデータが入っています。
表のデータの入っている所だけを縦に(Yの欄）
に取り出したいのですが、

INDEX($A$1:$G$6,INT((ROW(A1)-1)/7)+1,MOD(ROW(A1)-1,7)+1)
のような関数だと　空白のセルも「0」でもってきてしまいます。
データの部分だけを拾って　縦にならべる方法を知りたいです。
よろしくお願いします。

関数で解決するのは(私には)難しいと思いましたので、VBAでいかがでしょう?
Sub test()
  Dim myRng As Range, cn As Long
  Dim c As Range
  Set myRng = Range("A1:G6")
    For Each c In myRng
        If c.Value <> "" Then
            cn = cn + 1
            Range("Y" & cn).Value = c.Value
        End If
    Next c
End Sub

> Range("Y" & cn).Value = c.Value
> の所のを"Y4"と入れるとマクロが動きません。
Y4セルから値を入力するのなら、cnの開始値を4となるようにcn=3として調整します。

> 表示させるセル番号は実は"Y"という列番ではなく　例えば"Y4"とか先頭行も
> 微妙にズレるので
Range("Y" & cn).Value = c.Value　としていますが、
Cells(cn,"Y").Value = c.Value
とした方がわかり易かったりしますか?Cells(行,列)となります。

Sub test()
  Dim myRng As Range, cn As Long
  Dim c As Range
  Set myRng = Range("A1:G6") '値があるかを判断するセル範囲
  cn = 3 'cnの開始値を4とするため、ここでは3を設定します
    For Each c In myRng 'セル範囲を1個づつチェックします
        If c.Value <> "" Then 'セルの値が"" でない場合セルに値を入力します
            cn = cn + 1 'セルの値が""でない場合はcnの値をカウントアップします cn=4から始まります
            Range("Y" & cn).Value = c.Value 'Y列のcn行目に値を入力します
        End If
    Next c
End Sub

一寸、荒っぽいですが、
  Range(Range("Y4"), Range("Y4").End(xlDown)).Delete
としてみました。データがないときは・・・
Y4セルから下方向へ[Shift]+[Ctrl]+[↓]で選択されるセル範囲をクリアします。

Sub test()
  Dim myRng As Range, cn As Long
  Dim c As Range
  '↓Y4セルから下のセルをクリアします。
  Range(Range("Y4"), Range("Y4").End(xlDown)).Delete
  Set myRng = Range("A1:G6") '値があるかを判断するセル範囲
  cn = 3 'cnの開始値を4とするため、ここでは3を設定します
    For Each c In myRng 'セル範囲を1個づつチェックします
        If c.Value <> "" Then 'セルの値が"" でない場合セルに値を入力します
            cn = cn + 1 'セルの値が""でない場合はcnの値をカウントアップします cn=4から始まります
            Cells(cn, "Y").Value = c.Value 'Y列のcn行目に値を入力します
        End If
    Next c
End Sub

失礼しました。
Delete　を　Clear　に変更してください。
  Range(Range("Y4"), Range("Y4").End(xlDown)).Clear

シートでは[Delete]キーでクリアになるので、うっかり Delete(削除)と書いてしまいました。

> 罫線もクリアになりますね＾＾；
Clear を ClearContents　に変更してください。

以下のような指定ができます。
Clear：全て
ClearContents：値と数式
ClearFormats：書式 (色や罫線、条件付き書式など)