よねさんへ

　　いつも勉強させていただいております。
　どうしても、うまくいかないのでご教授お願いしたいです。

　
　　　　  A  　     B     C  　 D   　 E        F  ・・・　　I 　  J 　  K　　 L　　M　　　N  　　  　　
1行目　　氏名　 　日付　 ｻｲｽﾞ　数量　 単価　  金額  　　　　24.5  25.0　25.5　26.0  26.5  27.0
2行目　〇〇花子　R4.2.1  25.5　　3　　2,100    4,200
3行目  〇×太郎　R4.2.2  25.0　　1    2,000    2,000
4行目  ××治郎　R4.2.2  24.5 　 1    2,000    2,000
5行目　△△梅子　R4.2.3  25.5    2    2,100    4,200
6行目　●●花子　R4.2.5  25.0    4    2,200    2,200
7行目以降も続きます。

この様な表があるのですが、
I列の2行目に、C列の24.5に一致する最下行のD列の数量「1」を表示
J列の2行目に、C列の25.0に一致する最下行のD列の数量「4」を表示
K列の2行目に、C列の25.5に一致する最下行のD列の数量「2」を表示
L列、M列、N列も同様に表示させたいです。

自分なりにやってみましたが、うまくできませんでした。
よろしくお願いいたします。

XLOOKUP関数が使えるなら
=XLOOKUP(I1,$C$2:$C$6,$D$2:$D$6,"X",,-1)
で求めることができます。

３回目のワクチンの副作用で熱が出ていたので書く気が起きませんでした。
やっと、XLOOKUP関数が使えない場合を考えましたので書きます。
（1）データを逆順に並べ替えます。すると、VLOOKUP関数で求めることができます。
　　=VLOOKUP(I1,$C$2:$D$6,2,0)
（2）作業列を使います。
　　I2:N6セルを作業列とすると、
　　I2セルに　=IF($C2=I$1,COUNTIF($C$2:$C2,I$1),0)　と入力して、右方向や下方向へ数式をコピーします。
　　I7セルに　=IF(MAX(I$2:I$6)<>0,INDEX($D$2:$D$6,MATCH(MAX(I$2:I$6),I$2:I$6,0)),"X")
　　と入力して、右方向へコピーします。
（3）配列数式で処理できるようです。
　　=INDEX($D$2:$D$6,MATCH(2,1/($C$2:$C$6=I1)))
　　と入力して、[Ctrl]+[Shift]+[Enter]で確定してから数式をコピーします。
　　計算の意味はご自身で調べてください。
　　Web検索で見つけたもので、計算ができましたので書いてみました。